From f5262257d5f4d3951e3e8fd4d63ca9d9fd7878e3 Mon Sep 17 00:00:00 2001
From: Mark Riedesel <mark@klowner.com>
Date: Fri, 28 Mar 2025 09:53:00 -0500
Subject: [PATCH] neovim: add treesitter injection for bash into yaml for
 'commands' key

---
 .../nvim/after/queries/yaml/injections.scm    | 39 +++++++++++++++++++
 1 file changed, 39 insertions(+)
 create mode 100644 .config/nvim/after/queries/yaml/injections.scm

diff --git a/.config/nvim/after/queries/yaml/injections.scm b/.config/nvim/after/queries/yaml/injections.scm
new file mode 100644
index 0000000..017a331
--- /dev/null
+++ b/.config/nvim/after/queries/yaml/injections.scm
@@ -0,0 +1,39 @@
+;;extends
+; Woodpecker-CI ("commands")
+(block_mapping_pair
+  key: (flow_node) @_run
+  (#eq? @_run "commands")
+  value: (flow_node
+    (plain_scalar
+      (string_scalar) @injection.content)
+    (#set! injection.language "bash")))
+
+(block_mapping_pair
+  key: (flow_node) @_run
+  (#eq? @_run "commands")
+  value: (block_node
+    (block_scalar) @injection.content
+    (#set! injection.language "bash")
+    (#offset! @injection.content 0 1 0 0)))
+
+(block_mapping_pair
+  key: (flow_node) @_run
+  (#eq? @_run "commands")
+  value: (block_node
+    (block_sequence
+      (block_sequence_item
+        (flow_node
+          (plain_scalar
+            (string_scalar) @injection.content))
+        (#set! injection.language "bash")))))
+
+(block_mapping_pair
+  key: (flow_node) @_run
+  (#eq? @_run "commands")
+  value: (block_node
+    (block_sequence
+      (block_sequence_item
+        (block_node
+          (block_scalar) @injection.content
+          (#set! injection.language "bash")
+          (#offset! @injection.content 0 1 0 0))))))